多功能一键设置网络IP地址的bat批处理

admin 2018-9-3 433

将以下代码保存到 一个.bat的文件里,然后根据需求更改下配置 双击,有你想要的惊喜


::813711465@qq.com
@echo off
::双冒号表示注释,注释只能单独一行写,@表示不让执行的命令又显示在屏幕上
cls
::清屏
color 0A
::设置显示字体颜色
echo IP地址更改小工具 选定请按回车enter
::ip地址
set IP=192.168.31.101
::子网掩码
set MASK=255.255.255.0
::网关
set GATEWAY=192.168.31.1
::网络名称
set NAME="本地连接"
::dns
set DNS1="223.5.5.5" 
set DNS2="8.8.8.8"
@echo.
@echo    --------------------默认配置-----------------------
@echo.
@echo 更改%NAME%IP地址
@echo IP:%IP% 
@echo 子网掩码:%MASK% 
@echo 网关:%GATEWAY% 
@echo DNS1:%DNS1% 
@echo DNS2:%DNS2% 
@echo.
@echo    ---------------------------------------------------
:ENTER
echo.
echo.
echo    ------- 更改为默认配置的IP--- 请按 1  
echo    ------- 手动更改IP--------------- 请按 2 
echo    ------- 设置IP动态获取----------- 请按 3
echo    ------- 设置DNS动态获取---------- 请按 4
echo    ------- 手动设置DNS-------------- 请按 5
echo    ------- 显示网络配置信息--------- 请按 6
echo    ------- 退出--------------------- 请按 7
set /p KEY= ****** 您的选择是:
::  /p表示将KEY设置为输入行
if %KEY% == 1 goto ONE
if %KEY% == 2 goto TWO
if %KEY% == 3 goto THREE
if %KEY% == 4 goto FOUR
if %KEY% == 5 goto FIVE
if %KEY% == 6 goto SIX
if %KEY% == 7 goto EXIT
:TWO
ECHO 您选择了手工修改设置。
ECHO.
echo 默认IP地址是%IP%,回车输入默认地址
set /p IP= [请输入IP地址:]
echo.
echo 默认MASK是%MASK%,回车输入默认值
set /p MASK= [请输入 子网掩码 地址:]
echo.
echo 默认GATEWAY是%GATEWAY%,回车输入默认值
set /p GATEWAY= [请输入 网关 地址:]
echo.
:ONE
echo 正在自动更改IP......
netsh interface ip set address %NAME% static %IP% %MASK% %GATEWAY%
echo IP地址/子网掩码/网关设置完成
goto ENTER
:THREE
netsh interface ip set address name=%NAME% source=dhcp
echo IP地址设置完成
goto ENTER
:FOUR
netsh interface ip set dns name=%NAME% source=dhcp
echo dns设置完成
goto ENTER
:FIVE
echo 默认DNS1地址是%DNS1%,回车输入默认地址
set /p DNS1= [请输入DNS1地址:]
echo.
echo 默认DNS2地址是%DNS2%,回车输入默认地址
set /p DNS2= [请输入DNS2地址:]
echo.
echo 正在设置DNS......
netsh interface ip add dns %NAME% %DNS1% index=1 >nul
netsh interface ip add dns %NAME% %DNS2% index=2 >nul
echo dns设置完成
goto ENTER
:SIX
ipconfig /all
goto ENTER
:EXIT
pause
exit


最新回复 (0)
全部楼主
返回
发新帖
老师机论坛